//By [STELS]BendeR 06/2019
//Replication and usage w/o author agreement is forbidden

if(isDedicated||(!hasInterface)) exitWith {};
waitUntil { player == player };

b_rpg_list=[b_rpg1,b_rpg2,b_rpg3,b_rpg4,b_rpg5,b_rpg6,b_rpg7,b_rpg8,b_rpg9];
if(!(player in b_rpg_list)) exitWith {};
local_equip_select=1;

player createDiarySubject ["equip_select", "ВЫБОР СНАРЯЖЕНИЯ"];
player createDiaryRecord ["equip_select", ["Пояснения","Выбор работает только на брифенге.<br />Рекомендуется выбирать через 30с после прогрузки на брифинг.<br />Текущий выбор-самая верхняя строчка в разделе Выбранное снаряжение<br />Раздел Инструктаж-Мое отделение при работе скрипта не обновляется"]];
player createDiaryRecord ["equip_select", ["ВЫБОР СНАРЯЖЕНИЯ","
   <execute expression='local_equip_select=1;'>Вариант 1</execute>: <img image='"+getText (configfile >> "CfgWeapons" >> "launch_MRAWS_green_rail_F" >> "picture")+"' height=40 /> MAAWS Mod.0 <img image='"+getText (configfile >> "CfgMagazines" >> "MRAWS_HEAT_F" >> "picture")+"' height=30 />x2 <img image='"+getText (configfile >> "CfgMagazines" >> "MRAWS_HE_F" >> "picture")+"' height=30 />x2<br />
   <execute expression='local_equip_select=2;'>Вариант 2</execute>: <img image='"+getText (configfile >> "CfgWeapons" >> "launch_NLAW_F" >> "picture")+"' height=40 /> PCML <img image='"+getText (configfile >> "CfgMagazines" >> "NLAW_F" >> "picture")+"' height=30 />x2<br />
"]];   

_g=[] spawn {
   private   _local_equip_select_ons=0;
   private _update_briefing=False;
   private _str_equip="";
   
   waitUntil {(!isNil("WMT_pub_frzTimeLeft"))&&(!isNil("wmt_param_PrepareTime"))&&(!isNil("WMT_pub_frzState"))};

   while{(WMT_pub_frzTimeLeft>=(wmt_param_PrepareTime*60))&&(WMT_pub_frzState<3)} do {
      _update_briefing=False;
      if(local_equip_select!=_local_equip_select_ons) then {
         player removeWeapon "launch_MRAWS_green_rail_F";
         player removeWeapon "launch_NLAW_F";
         player removeMagazines "MRAWS_HE_F";
         player removeMagazines "MRAWS_HEAT_F";
         player removeMagazines "NLAW_F";
         
         switch(local_equip_select) do {
               case 1: {
                        player addWeapon "launch_MRAWS_green_rail_F";
                        for "_i" from 1 to 2 do {player addItemToBackpack "MRAWS_HEAT_F";};
                        for "_i" from 1 to 2 do {player addItemToBackpack "MRAWS_HE_F";};
                     };
               case 2: {
                        player addWeapon "launch_NLAW_F";
                        for "_i" from 1 to 2 do {player addItemToBackpack "NLAW_F";};
                     };
         };
         
         _update_briefing=True;
         _local_equip_select_ons=local_equip_select;
      };
      
      
      if(_update_briefing) then{
         switch(local_equip_select) do {
            case 1: {   
               _str_equip="MAAWS Mod.0";
            };
            case 2: {
               _str_equip="NLAW";
            };
         };
         player createDiaryRecord ["equip_select", ["Выбранное снаряжение",_str_equip]];
      };
      
      uiSleep(1);
   };
};