Удаление БК у техники.

Поиск

Новые сообщения · Подписки

Страница 1 из 1
1

Удаление БК у техники. (Как удалять определённое вооружение на технике?)

Удаление БК у техники.

Distrak

Среда, 23.03.2016, 09:48

Пост №: 1

Пользователь

Одиночка

Ситуация. У меня на карте стоит Ми-24 (ФАБ), надо сделать чтобы на нём было не 2 фаба, а 1 ну или убрать опред. количество бк на вертолёте.
Меня интересует процесс того, как узнать ID того или иного вооружения техники и как его убрать (скрипт).
P.S. у меня раньше был этот скрипт, но я его потерял. Но тот скрипт был не тот, т.к он убирал полностью бк с техники.

Автор темы

inwel

Среда, 23.03.2016, 11:05

Пост №: 2

Если тебе для РХС, то в их документации можно найти:
http://class.rhsmods.org/

Пример того, как убрать НУРСы у вертолёта Пауни:

Код

this removeMagazinesTurret [""24Rnd_missiles"",[-1]]";

Также для регулировки количества бк, можно подвигать ползунок в редакторе.
Идеального способа задать нужное количество бк нет. Либо вы добавляете/убираете "магазины" определённого оружия (т.е. если в "магазине" пушки 20 снарядов, то сделать 10, не затрагивая другое вооружение, не получится. Можно сделать 0, 20, 40 и так далее.), либо вы двигаете ползунок и изменяете бк всех видов вооружений сразу.

def

Суббота, 26.03.2016, 15:26

Пост №: 3

Цитата Distrak (

)

Меня интересует процесс того, как узнать ID того или иного вооружения техники и как его убрать (скрипт).

Чтобы закрыть этот вопрос раз и навсегда,
сделал маленькую миссию на основе скрипта из бики (можно из нее взять только init.sqf, если что) для картодела
https://yadi.sk/d/HQqbUmv7qVVDu

Последовательность действий:
1) залезаешь в технику
2) в action menu появляется команда "Copy vehicle info"

3) Крутишь колесом, выбираешь и запускаешь ее
4) В буфер обмена копируется инфа о возможном и текущем вооружении техники

Ликбез:
- у техники может быть несколько туррелей;
- туррель это сущность, к которой могут быть прикреплены орудия;
- орудий может быть несколько;
- в туррель могут быть загружены боеприпасы (причем, по-моему, не обязательно от имеющихся на туррели орудий);
- командами можно добавить\удалить орудия с туррели, добавить\удалить боеприпас орудий в туррель.

Интерпретация результата:
- наклонным результат, выгружаемый в буфер обмена при запуске экшена в технике);
- жирным комментарии, поясняющие полученный результат.

Пример для ми24б фаб:

"----------------------------------------
Vehicle RHS_Mi24P_AT_vdv info: Название класса техники
Turret №-1 weapons: Номер туррели
Weapon [rhs_weap_CMFlareLauncher] possible ammo: Название орудия указанной туррели
- 60Rnd_CMFlareMagazine В этом разделе перечисляются виды боеприпаса, которые подошли бы для указанного орудия
- 120Rnd_CMFlareMagazine
- 240Rnd_CMFlareMagazine конкретно это - обманки от вражеских ракет
- 60Rnd_CMFlare_Chaff_Magazine
- 120Rnd_CMFlare_Chaff_Magazine
- 240Rnd_CMFlare_Chaff_Magazine
- 192Rnd_CMFlare_Chaff_Magazine
- 168Rnd_CMFlare_Chaff_Magazine
- 300Rnd_CMFlare_Chaff_Magazine
Weapon [RHS_weap_GSh30] possible ammo: Следующее орудие
- rhs_mag_gsh30_ofzt_750
- rhs_mag_gsh30_ofzt_250
- rhs_mag_gsh30_bt_750
- rhs_mag_gsh30_bt_250
Weapon [rhs_weap_s8] possible ammo:
- rhs_mag_s8_12
- rhs_mag_s8_40
- rhs_mag_s8_80
- rhs_mag_s8_120

Turret №0 weapons: Следующая туррель
Weapon [rhs_weap_9K114_launcher] possible ammo:
- rhs_mag_9K114

В этом разделе перечислены боеприпасы, которые действительно загружены в туррели текущей единицы техники
Current ammo set (- ammo [turret №]):
- rhs_mag_gsh30_ofzt_750 ([-1])
- rhs_mag_s8_40 ([-1])
- 168Rnd_CMFlare_Chaff_Magazine ([-1])
- rhs_mag_ataka_tube ([0])
- rhs_mag_ataka_tube ([0])
- rhs_mag_ataka_tube ([0])
- rhs_mag_ataka_tube ([0])
- rhs_mag_b8v20a_pod ([0])
- rhs_mag_ataka_tube_2 ([0])
- rhs_mag_ataka_tube_2 ([0])
- rhs_mag_ataka_tube_2 ([0])
- rhs_mag_ataka_tube_2 ([0])
- rhs_mag_9K114 ([0])
- rhs_mag_9K114 ([0])
- rhs_mag_9K114 ([0])
- rhs_mag_9K114 ([0])
- rhs_mag_9K114 ([0])
- rhs_mag_9K114 ([0])
- rhs_mag_9K114 ([0])
- rhs_mag_9K114 ([0])
Итого - в туррели "водителя" (пилота) (№ -1) по 1 "обойме" боеприпасов следующих типов:
- rhs_mag_gsh30_ofzt_750 ([-1])
- rhs_mag_s8_40 ([-1])
- 168Rnd_CMFlare_Chaff_Magazine ([-1])
Во второй туррели:
- 4х rhs_mag_ataka_tube (подозреваю, что это какие-то хреновины для запуска ракет, не боеприпас)
- 1х rhs_mag_b8v20a_pod
- 4х rhs_mag_ataka_tube_2
- 8х rhs_mag_9K114

----------------------------------------"
Примеры команд:
Добавить боеприпас определенного типа в туррель
https://community.bistudio.com/wiki/addMagazineTurret
пример: vehicle player addMagazineTurret ["rhs_mag_gsh30_ofzt_750",[-1]] - добавили боеприпас на 750 зарядов

Убрать боеприпас определенного типа из туррели
https://community.bistudio.com/wiki/removeMagazineTurret
пример: vehicle player removeMagazineTurret ["168Rnd_CMFlare_Chaff_Magazine",[-1]] - убрали обманки

убрать весь боеприпас данного типа из туррели
https://community.bistudio.com/wiki/removeMagazinesTurret
к примеру удалить все 8 ракет:
VEH removeMagazinesTurret ["rhs_mag_9K114",[0]];

убрать орудие из туррели
https://community.bistudio.com/wiki/removeWeaponTurret
Пример: VEH removeWeaponTurret ["rhs_weap_9K114_launcher",[0]]; - убрали ракетницы

добавить орудие в туррель
https://community.bistudio.com/wiki/addWeaponTurret
пример: VEH addWeaponTurret ["LMG_M200",[-1]]; - добавили ручной пулемет пилоту вертолета

п.с.
если ссылка не работает, код init.sqf под спойлером:

Код

/**/
funcGetTurretsWeapons = {
     private ["_br","_result", "_getAnyMagazines", "_class"];
    _br = toString [13,10];
        _result = "----------------------------------------";
    _getAnyMagazines = {
          private ["_weapon", "_mags"];
          _weapon = configFile >> "CfgWeapons" >> _this;
          _mags = [];
          {
              _mags = _mags + getArray (
                  (if (_x == "this") then { _weapon } else { _weapon >> _x }) >> "magazines"
              )
          } foreach getArray (_weapon >> "muzzles");
  for "_i" from 0 to (count (_mags)-1) do
  {
   _result = _result + _br + format["   - %1",(_mags select _i)];
  };
//         _mags
    };

    _result = _result + _br +  format["Vehicle %1 info:",typeof (vehicle player)];
    for "_i" from -1 to 7 do {
  if ((count ((vehicle player) weaponsTurret [_i])) != 0) then
  {
   _result = _result + _br + format[" Turret №%1 weapons: ",_i];
   _class = (vehicle player) weaponsTurret [_i];
   for "_j" from 0 to ((count _class)-1) do
   {
    _result = _result + _br + format["  Weapon [%1] possible ammo: ",_class select _j];
    ((_class select _j) call _getAnyMagazines);
   };
   _result = _result + _br;
  };
    };
    _result = _result + _br;
    _result = _result + _br + format[" Current ammo set (- ammo [turret №]):"];
    _class = magazinesAllTurrets (vehicle player);
    for "_i" from 0 to (count (_class)-1) do
    {
  _result = _result + _br + format["  - %1 (%2)",(_class select _i select 0),(_class select _i select 1)];
    };
        _result = _result + _br + "----------------------------------------";

     copytoclipboard str _result;
    hint str(_result);
    _result;
};

player addAction ["<t color='#dd2200'>Copy vehicle info</t>", {(vehicle player) call funcGetTurretsWeapons},"" , -1, false,true, "", "(vehicle player) != player"];
player addAction ["<t color='#22dd00'>Current vehicle ammo</t>", {copytoclipboard str(magazinesAmmoFull (vehicle player));},"" , -1, false,true, "", "(vehicle player) != player"];

Сообщение отредактировал def - Понедельник, 04.04.2016, 22:18

Distrak

Суббота, 26.03.2016, 18:55

Пост №: 4

Пользователь

Одиночка

Цитата def (

)

Администратор игр
Сообщений: 195
21
Чтобы закрыть этот вопрос раз и навсегда:

Спасибо!

Автор темы

Удаление БК у техники. (Как удалять определённое вооружение на технике?)

Страница 1 из 1
1